From ded6dddb89cade026e592cd386790b5b10e6fe00 Mon Sep 17 00:00:00 2001
From: Manuel Canales Esparcia <manuel@linuxfromscratch.org>
Date: Sat, 8 May 2004 14:19:53 +0000
Subject: Updated the stylesheets to their current version.

git-svn-id: http://svn.linuxfromscratch.org/LFS/trunk/BOOK@3529 4aa44e1e-78dd-0310-a6d2-fbcd4c07a689
---
 stylesheets/print/lfs-index.xsl     | 127 ++++++++++++++++++++++++++++++++++++
 stylesheets/print/lfs-pagesetup.xsl | 120 ++++++++++++++++++++++++++++++++++
 2 files changed, 247 insertions(+)
 create mode 100644 stylesheets/print/lfs-index.xsl
 create mode 100644 stylesheets/print/lfs-pagesetup.xsl

(limited to 'stylesheets/print')

diff --git a/stylesheets/print/lfs-index.xsl b/stylesheets/print/lfs-index.xsl
new file mode 100644
index 000000000..63a014a82
--- /dev/null
+++ b/stylesheets/print/lfs-index.xsl
@@ -0,0 +1,127 @@
+<?xml version='1.0' encoding='ISO-8859-1'?>
+<!DOCTYPE xsl:stylesheet [
+<!ENTITY lowercase "'abcdefghijklmnopqrstuvwxyz'">
+<!ENTITY uppercase "'ABCDEFGHIJKLMNOPQRSTUVWXYZ'">
+<!ENTITY primary   'normalize-space(concat(primary/@sortas, primary[not(@sortas)]))'>
+<!ENTITY scope 'count(ancestor::node()|$scope) = count(ancestor::node())'>
+]> 
+
+<!-- Version 0.9 - Manuel Canales Esparcia <macana@lfs-es.org> -->
+
+<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
+                xmlns:fo="http://www.w3.org/1999/XSL/Format"
+                version="1.0">
+
+    <!--Title-->
+  <xsl:template match="index" mode="title.markup">
+  	<xsl:param name="allow-anchors" select="0"/>
+    <xsl:text>Index of packages and important installed files</xsl:text>
+	</xsl:template>
+
+  	<!-- Divisions-->
+  <xsl:template match="indexterm" mode="index-div">
+    <xsl:param name="scope" select="."/>
+    <xsl:variable name="key"
+                  select="translate(substring(&primary;, 1, 1),&lowercase;,&uppercase;)"/>
+    <xsl:variable name="divtitle" select="translate($key, &lowercase;, &uppercase;)"/>
+    <xsl:if test="key('letter', $key)[&scope;]
+                  [count(.|key('primary', &primary;)[&scope;][1]) = 1]">
+      <fo:block>
+        <xsl:if test="contains(concat(&lowercase;, &uppercase;), $key)">
+          <xsl:call-template name="indexdiv.title">
+            <xsl:with-param name="titlecontent">
+              <xsl:choose>
+                <xsl:when test="$divtitle = 'A'">
+                  <xsl:text>Packages</xsl:text>
+              </xsl:when>
+              <xsl:when test="$divtitle = 'B'">
+                  <xsl:text>Programs</xsl:text>
+              </xsl:when>
+              <xsl:when test="$divtitle = 'C'">
+                  <xsl:text>Libraries</xsl:text>
+              </xsl:when>
+              <xsl:when test="$divtitle = 'D'">
+                  <xsl:text>Scripts</xsl:text>
+              </xsl:when>
+              <xsl:when test="$divtitle = 'E'">
+                  <xsl:text>Others</xsl:text>
+              </xsl:when>
+              <xsl:otherwise>
+                <xsl:value-of select="$divtitle"/>
+              </xsl:otherwise>
+            </xsl:choose>
+            </xsl:with-param>
+          </xsl:call-template>
+        </xsl:if>
+        <fo:block>
+          <xsl:apply-templates select="key('letter', $key)[&scope;]
+                                      [count(.|key('primary', &primary;)[&scope;][1])=1]"
+                              mode="index-primary">
+            <xsl:sort select="translate(&primary;, &lowercase;, &uppercase;)"/>
+            <xsl:with-param name="scope" select="$scope"/>
+          </xsl:apply-templates>
+        </fo:block>
+      </fo:block>
+    </xsl:if>
+  </xsl:template>
+
+  	<!-- The separator -->
+  <xsl:template match="indexterm" mode="reference">
+    <xsl:param name="scope" select="."/>
+    <xsl:text>:   </xsl:text>
+    	<xsl:call-template name="reference">
+        <xsl:with-param name="zones" select="normalize-space(@zone)"/>
+        <xsl:with-param name="scope" select="$scope"/>
+      </xsl:call-template>
+  </xsl:template>
+  
+  	<!--Bookmarks-->
+  <xsl:template name="reference">
+    <xsl:param name="scope" select="."/>
+    <xsl:param name="zones"/>
+    <xsl:choose>
+      <xsl:when test="contains($zones, ' ')">
+        <xsl:variable name="zone" select="substring-before($zones, ' ')"/>
+        <xsl:variable name="zone2" select="substring-after($zones, ' ')"/>
+        <xsl:variable name="target" select="key('id', $zone)[&scope;]"/>
+        <xsl:variable name="target2" select="key('id', $zone2)[&scope;]"/>
+        <xsl:variable name="id">
+          <xsl:call-template name="object.id">
+            <xsl:with-param name="object" select="$target[1]"/>
+          </xsl:call-template>
+        </xsl:variable>
+        <xsl:variable name="id2">
+          <xsl:call-template name="object.id">
+            <xsl:with-param name="object" select="$target2[1]"/>
+          </xsl:call-template>
+        </xsl:variable>
+        <fo:basic-link internal-destination="{$id}">
+          <xsl:apply-templates select="$target" mode="page.citation">
+          	<xsl:with-param name="id" select="$id"/>
+          </xsl:apply-templates>
+        </fo:basic-link>
+          <xsl:text> ,  </xsl:text>
+        <fo:basic-link internal-destination="{$id2}">
+          <xsl:apply-templates select="$target2" mode="page.citation">
+          	<xsl:with-param name="id" select="$id2"/>
+          </xsl:apply-templates>
+        </fo:basic-link>
+      </xsl:when>
+      <xsl:otherwise>
+        <xsl:variable name="zone" select="$zones"/>
+        <xsl:variable name="target" select="key('id', $zone)[&scope;]"/>
+        <xsl:variable name="id">
+          <xsl:call-template name="object.id">
+            <xsl:with-param name="object" select="$target[1]"/>
+          </xsl:call-template>
+        </xsl:variable>
+        <fo:basic-link internal-destination="{$id}">
+          <xsl:apply-templates select="$target" mode="page.citation">
+          	<xsl:with-param name="id" select="$id"/>
+          </xsl:apply-templates>
+        </fo:basic-link>
+      </xsl:otherwise>
+    </xsl:choose>
+  </xsl:template>
+
+</xsl:stylesheet>
diff --git a/stylesheets/print/lfs-pagesetup.xsl b/stylesheets/print/lfs-pagesetup.xsl
new file mode 100644
index 000000000..44e91acc2
--- /dev/null
+++ b/stylesheets/print/lfs-pagesetup.xsl
@@ -0,0 +1,120 @@
+<?xml version='1.0' encoding='ISO-8859-1'?>
+
+<!-- Version 0.9 - Manuel Canales Esparcia <macana@lfs-es.org> -->
+
+<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
+                xmlns:fo="http://www.w3.org/1999/XSL/Format"
+                version="1.0">
+
+  	<!-- Force section1's onto a new page -->
+  <xsl:attribute-set name="section.level1.properties">
+  	<xsl:attribute name="break-after">
+    	<xsl:choose>
+  			<xsl:when test="not(position()=last())">
+      		<xsl:text>page</xsl:text>
+    		</xsl:when>
+        <xsl:otherwise>
+      		<xsl:text>auto</xsl:text>
+        </xsl:otherwise>
+      </xsl:choose>
+    </xsl:attribute>
+  </xsl:attribute-set>
+
+		<!-- Header -->
+  <xsl:template name="header.content">
+  	<xsl:param name="sequence" select="''"/>
+		<fo:block>
+      <xsl:attribute name="text-align">
+        <xsl:choose>
+          <xsl:when test="$sequence = 'first' or $sequence = 'odd'">right</xsl:when>
+          <xsl:otherwise>left</xsl:otherwise>
+        </xsl:choose>
+      </xsl:attribute>
+      <xsl:value-of select="/book/bookinfo/title"/>
+      <xsl:text> - </xsl:text>
+      <xsl:value-of select="/book/bookinfo/subtitle"/>
+    </fo:block>
+  </xsl:template>
+
+  <xsl:template name="header.table">
+  	<xsl:param name="sequence" select="''"/>
+    <xsl:param name="gentext-key" select="''"/>
+    <xsl:choose>
+      <xsl:when test="$gentext-key = 'book' or $sequence = 'blank'"/>
+      <xsl:otherwise>
+      	<xsl:call-template name="header.content">
+					<xsl:with-param name="sequence" select="$sequence"/>
+				</xsl:call-template>
+      </xsl:otherwise>
+    </xsl:choose>
+  </xsl:template>
+
+		<!-- Centered titles for book and part -->
+  <xsl:template name="book.titlepage">
+    <fo:block space-before="2in">
+      <fo:block>
+        <xsl:call-template name="book.titlepage.before.recto"/>
+        <xsl:call-template name="book.titlepage.recto"/>
+      </fo:block>
+      <fo:block>
+        <xsl:call-template name="book.titlepage.before.verso"/>
+        <xsl:call-template name="book.titlepage.verso"/>
+      </fo:block>
+      <xsl:call-template name="book.titlepage.separator"/>
+    </fo:block>
+  </xsl:template>
+
+  <xsl:template name="part.titlepage">
+    <fo:block xmlns:fo="http://www.w3.org/1999/XSL/Format">
+      <fo:block space-before="2.5in">
+        <xsl:call-template name="part.titlepage.before.recto"/>
+        <xsl:call-template name="part.titlepage.recto"/>
+      </fo:block>
+      <fo:block>
+        <xsl:call-template name="part.titlepage.before.verso"/>
+        <xsl:call-template name="part.titlepage.verso"/>
+      </fo:block>
+      <xsl:call-template name="part.titlepage.separator"/>
+    </fo:block>
+  </xsl:template>
+
+  	<!-- Margins -->
+  <xsl:param name="page.margin.inner">1in</xsl:param>
+  <xsl:param name="page.margin.outer">0.5in</xsl:param>
+  <xsl:param name="title.margin.left">-1pc</xsl:param>
+  <xsl:attribute-set name="normal.para.spacing">
+    <xsl:attribute name="space-before.optimum">0.8em</xsl:attribute>
+    <xsl:attribute name="space-before.minimum">0.6em</xsl:attribute>
+    <xsl:attribute name="space-before.maximum">1em</xsl:attribute>
+  </xsl:attribute-set>
+  <xsl:attribute-set name="list.block.spacing">
+    <xsl:attribute name="space-before.optimum">0.8em</xsl:attribute>
+    <xsl:attribute name="space-before.minimum">0.6em</xsl:attribute>
+    <xsl:attribute name="space-before.maximum">1em</xsl:attribute>
+    <xsl:attribute name="space-after.optimum">0.8em</xsl:attribute>
+    <xsl:attribute name="space-after.minimum">0.6em</xsl:attribute>
+    <xsl:attribute name="space-after.maximum">1em</xsl:attribute>
+  </xsl:attribute-set>
+  <xsl:attribute-set name="list.item.spacing">
+    <xsl:attribute name="space-before.optimum">0.6em</xsl:attribute>
+    <xsl:attribute name="space-before.minimum">0.4em</xsl:attribute>
+    <xsl:attribute name="space-before.maximum">0.8em</xsl:attribute>
+  </xsl:attribute-set>
+  <xsl:attribute-set name="verbatim.properties">
+    <xsl:attribute name="space-before.minimum">0.6em</xsl:attribute>
+    <xsl:attribute name="space-before.optimum">0.8em</xsl:attribute>
+    <xsl:attribute name="space-before.maximum">1em</xsl:attribute>
+    <xsl:attribute name="space-after.minimum">0.6em</xsl:attribute>
+    <xsl:attribute name="space-after.optimum">0.8em</xsl:attribute>
+    <xsl:attribute name="space-after.maximum">1em</xsl:attribute>
+  </xsl:attribute-set>
+
+  	<!-- Others-->
+  <xsl:param name="header.rule" select="0"></xsl:param>
+  <xsl:param name="footer.rule" select="0"></xsl:param>
+	<xsl:param name="marker.section.level" select="-1"></xsl:param>
+
+  	<!-- Dropping a blank page -->
+	<xsl:template name="book.titlepage.separator"/>
+
+</xsl:stylesheet>
-- 
cgit v1.2.3-54-g00ecf